***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 16, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6801   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.18		 kp = 18.5)
.model  dds   d(
+   is = 1.072e-10	  n = 1.388		   rs = 3.063e-2		ikf = 3.245e-1
+   eg = 1.100	       trs1 = 1.374e-3		 tikf = 5.2e-3)
.model  dbody d(
+   is = 1.072e-10	  n = 1.388		   rs = 3.063e-2		ikf = 3.245e-1
+   eg = 1.100	       trs1 = 1.374e-3		 tikf = 5.2e-3)
+  cjo = 9.529e-11	  m = 4.121e-1		   vj = 1.656e-1
+   bv = 33		ibv = 250e-6		 tbv1 = 7.550e-4		 tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 3.317e-10	  m = 6.277e-1		   vj = 3.566e-1)
.param
+  cgs = 5.959e-12	cgd = 3.211e-12
+   rd = 4.141e-2	 ra = 1.152e-2		  trd = 4.506e-3
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0   , 0   ),
+ (0.5 , 0.5 ),
+ (1   , 1   ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 3   ),
+ (4   , 3.8 ),
+ (4.5 , 4   ),
+ (5   , 4.3 ),
+ (6   , 4.8 ),
+ (8   , 5.5 ),
+ (10  , 6   ),
+ (12  , 6.2 ),
+ (15  , 6.3 ))
egt	  1  2t   value = {2.687e-4*limit(v(2t,3),-2,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
